RSS 是一種“輕量級、多用途、可擴展的元數據描述及聯合推廣格式”，也可以理解為一種規范。它本身是一種 XML 格式，用于為內容整合客戶端提供選擇性的、匯總過的 Web 內容。如今，許多站點都開
始通過創建 RSS feed 向瀏覽者提供內容整合服務，提供新聞、站點內容的更新等等。瀏覽者可以通過一些客戶端軟件方便地得到這些組織、匯總了的信息。
那么，怎么在我們自己的網站上創建 RSS feed 呢？下面我以 Asp+Access 為例介紹一下。
既然 RSS 是一種 XML 格式的文檔，那么我們就應當可以對后臺數據庫中的數據按照條件進行篩選、組織，然后通過 ASP 生成 XML 格式的數據流，最后發送到客戶端進行瀏覽。
數據的選取、匯集是 Asp 的拿手好戲，關鍵在于怎么生成 XML 格式的數據流。其實 Asp 也已經有自己的解決辦法，就是在寫數據前對 response 對象的 ContentType 屬性進行定義。如果 response.ContentType 的取值為 "text/xml"，就會向瀏覽者發送 XML 格式的數據流。
在 IE 瀏覽器中調用 RSS 源的方法和普通的鏈接沒有什么區別，格式是：
<a type="application/rss+xml" href="RssFeed.asp">RSS說明</a>
其中 type="application/rss+xml" 加不加好象沒有什么區別。
以下程序段是創建我的網站(goaler.xicp.net)上的“某個欄目”欄目的 RSS feed 的源代碼，文件名為 RssFeed_news.asp。
其中，變量 sXmlClear 用于聲明產生的文檔是一段 XML 格式的文檔，該聲明是可選的，以保持與舊版本 XML 的向后兼容性。
sRssHead 定義 Rss 的基本元素。RSS feed 通常由 4 個主要元素構成：<channel>，<image>，<item> 和 <textinput>。其中，<channel> 元素是必需的，<item> 元素至少要出現一次。<textinput> 和 <image> 元素是可選的，是否使用要視具體情況而定。
<channel> 元素包含 Channel(RSS feed 的來源)的一個簡單描述。<title> 是頻道的名稱/標題；<link> 是與頻道內容對應的包含了完整內容的那個網頁的 URL；<description> 是與 <channel> 的內容有關的簡單描述；<language> 代表語言。還有一些別的屬性，不是太常用。
<item> 元素用于對數據庫中的記錄進行描述。<item> 一般有若干項，對應了一個 Rss feed 的數據集合。
<!-Filename：RssFeed_news.asp:-->
<% Option explicit %>
<!-- #include file="conn.asp" -->
<%
Dim sSQL, rs, sCrLf, sXmlClear, sRssHead, sRssEnd
sCrLf = chr(13) & chr(10) '回車+換行
sXmlClear = "<?xml version='1.0' encoding='gb2312'?>" & sCrLf
sRssHead = "<rss version='2.0'>" & sCrLf
sRssHead = sRssHead & "<channel>" & sCrLf
sRssHead = sRssHead & "<title>Goaler's Blog </title>" & sCrLf
sRssHead = sRssHead & "<description> Goaler's Blog </description>" & sCrLf
sRssHead = sRssHead & "<link></link>" & sCrLf
sRssHead = sRssHead & "<language>zh-cn</language>" & sCrLf
sRssHead = sRssHead & "<docs>Goaler's Blog </docs>" & sCrLf
sRssHead = sRssHead & "<generator>Rss Generator By goaler.xicp.net</generator>" & sCrLf
sRssEnd = "</channel></rss>"
Response.CharSet="gb2312" '數據集
Response.ContentType="text/xml" '數據流格式定義
'輸出：
Response.write sXmlClear
Response.write sRssHead
sSQL="select top 15 * from news order by sortid desc"
Set rs = Server.CreateObject("ADODB.Recordset")
rs.Open sSQL, s_Conn, 1, 1
if not (rs.eof and rs.bof) then
do while not rs.eof
response.write "<item>" & sCrLf
response.write "<title> " & rs("f_topic") & " </title>" & sCrLf
response.write "<link> " & "/show_new.asp?autoid=" & rs("f_i_autoid") & " </link>" & sCrLf
response.write "<author> " & rs("f_author") & " </author>" & sCrLf
response.write "<pubDate> " & rs("f_datetime") & " </pubDate>" & sCrLf
response.write "</item>" & sCrLf & sCrLf
rs.movenext
loop
end if
rs.close
set rs=nothing
Response.write sRssEnd
%>
IE 中的調用格式是：<a href="/RssFeed_news.asp">技術新聞RSS</a>。如果用一些客戶端軟件訂閱該 RSS，訂閱的 Url 就是/RssFeed_news.asp。