亚洲JIZZJIZZ妇女,亚洲伊人久久精品影院,亚洲偷偷自拍高清

ORACLE PL/SQL編程詳細(xì)之四：把游標(biāo)說透

本篇主要內(nèi)容如下：

4.1 游標(biāo)概念

4.1.1 處理顯式游標(biāo)

4.1.2 處理隱式游標(biāo)

4.1.3 關(guān)于 NO_DATA_FOUND 和 %NOTFOUND的區(qū)別

4.1.4 使用游標(biāo)更新和刪除數(shù)據(jù)

4.2 游標(biāo)變量

4.2.1 聲明游標(biāo)變量

4.2.2 游標(biāo)變量操作

游標(biāo)的使用

在 PL/SQL 程序中，對于處理多行記錄的事務(wù)經(jīng)常使用游標(biāo)來實(shí)現(xiàn)。

4.1 游標(biāo)概念

在PL/SQL塊中執(zhí)行SELECT、INSERT、DELETE和UPDATE語句時(shí)，ORACLE會(huì)在內(nèi)存中為其分配上下文區(qū)（Context Area），即緩沖區(qū)。游標(biāo)是指向該區(qū)的一個(gè)指針，或是命名一個(gè)工作區(qū)（Work Area），或是一種結(jié)構(gòu)化數(shù)據(jù)類型。它為應(yīng)用等直觀提供了一種對具有多行數(shù)據(jù)查詢結(jié)果集中的每一行數(shù)據(jù)分別進(jìn)行單獨(dú)處理的方法，是設(shè)計(jì)嵌入式SQL語句的應(yīng)用程序的常用編程方式。

在每個(gè)用戶會(huì)話中，可以同時(shí)打開多個(gè)游標(biāo)，其數(shù)量由數(shù)據(jù)庫初始化參數(shù)文件中的OPEN_CURSORS參數(shù)定義。

對于不同的SQL語句，游標(biāo)的使用情況不同：

SQL語句	游標(biāo)
非查詢語句	隱式的
結(jié)果是單行的查詢語句	隱式的或顯示的
結(jié)果是多行的查詢語句	顯示的

4.1.1 處理顯式游標(biāo)

1. 顯式游標(biāo)處理

顯式游標(biāo)處理需四個(gè) PL/SQL步驟:

l 定義/聲明游標(biāo)：就是定義一個(gè)游標(biāo)名，以及與其相對應(yīng)的SELECT 語句。

格式：

    CURSOR cursor_name[(parameter[, parameter]…)]
           [RETURN datatype]
    IS
        select_statement;

游標(biāo)參數(shù)只能為輸入?yún)?shù)，其格式為：

parameter_name [IN] datatype [{:= | DEFAULT} expression]

在指定數(shù)據(jù)類型時(shí)，不能使用長度約束。如NUMBER(4),CHAR(10) 等都是錯(cuò)誤的。

[RETURN datatype]是可選的，表示游標(biāo)返回?cái)?shù)據(jù)的數(shù)據(jù)。如果選擇，則應(yīng)該嚴(yán)格與select_statement中的選擇列表在次序和數(shù)據(jù)類型上匹配。一般是記錄數(shù)據(jù)類型或帶“%ROWTYPE”的數(shù)據(jù)。

l 打開游標(biāo)：就是執(zhí)行游標(biāo)所對應(yīng)的SELECT 語句，將其查詢結(jié)果放入工作區(qū)，并且指針指向工作區(qū)的首部，標(biāo)識(shí)游標(biāo)結(jié)果集合。如果游標(biāo)查詢語句中帶有FOR UPDATE選項(xiàng)，OPEN 語句還將鎖定數(shù)據(jù)庫表中游標(biāo)結(jié)果集合對應(yīng)的數(shù)據(jù)行。

格式：

OPEN cursor_name[([parameter =>] value[, [parameter =>] value]…)];

在向游標(biāo)傳遞參數(shù)時(shí)，可以使用與函數(shù)參數(shù)相同的傳值方法，即位置表示法和名稱表示法。PL/SQL 程序不能用OPEN 語句重復(fù)打開一個(gè)游標(biāo)。

l 提取游標(biāo)數(shù)據(jù)：就是檢索結(jié)果集合中的數(shù)據(jù)行，放入指定的輸出變量中。

格式：

FETCH cursor_name INTO {variable_list | record_variable };

執(zhí)行FETCH語句時(shí)，每次返回一個(gè)數(shù)據(jù)行，然后自動(dòng)將游標(biāo)移動(dòng)指向下一個(gè)數(shù)據(jù)行。當(dāng)檢索到最后一行數(shù)據(jù)時(shí)，如果再次執(zhí)行FETCH語句，將操作失敗，并將游標(biāo)屬性%NOTFOUND置為TRUE。所以每次執(zhí)行完FETCH語句后，檢查游標(biāo)屬性%NOTFOUND就可以判斷FETCH語句是否執(zhí)行成功并返回一個(gè)數(shù)據(jù)行，以便確定是否給對應(yīng)的變量賦了值。

l 對該記錄進(jìn)行處理；

l 繼續(xù)處理，直到活動(dòng)集合中沒有記錄；

l 關(guān)閉游標(biāo)：當(dāng)提取和處理完游標(biāo)結(jié)果集合數(shù)據(jù)后，應(yīng)及時(shí)關(guān)閉游標(biāo)，以釋放該游標(biāo)所占用的系統(tǒng)資源，并使該游標(biāo)的工作區(qū)變成無效，不能再使用FETCH 語句取其中數(shù)據(jù)。關(guān)閉后的游標(biāo)可以使用OPEN 語句重新打開。

格式：

CLOSE cursor_name;

注：定義的游標(biāo)不能有INTO 子句。

例1. 查詢前10名員工的信息。

DECLARE
   CURSOR c_cursor
   IS SELECT first_name || last_name, Salary
   FROM EMPLOYEES
   WHERE rownum<11;
   v_ename  EMPLOYEES.first_name%TYPE;
   v_sal    EMPLOYEES.Salary%TYPE;
BEGIN
  OPEN c_cursor;
  FETCH c_cursor INTO v_ename, v_sal;
  WHILE c_cursor%FOUND LOOP
     DBMS_OUTPUT.PUT_LINE(v_ename||'---'||to_char(v_sal) );
     FETCH c_cursor INTO v_ename, v_sal;
  END LOOP;
  CLOSE c_cursor;
END;

例2. 游標(biāo)參數(shù)的傳遞方法。

DECLARE
  DeptRec    DEPARTMENTS%ROWTYPE;
  Dept_name  DEPARTMENTS.DEPARTMENT_NAME%TYPE;
  Dept_loc   DEPARTMENTS.LOCATION_ID%TYPE;
  CURSOR c1 IS
  SELECT DEPARTMENT_NAME, LOCATION_ID FROM DEPARTMENTS
  WHERE DEPARTMENT_ID <= 30;

  CURSOR c2(dept_no NUMBER DEFAULT 10) IS
    SELECT DEPARTMENT_NAME, LOCATION_ID FROM DEPARTMENTS
    WHERE DEPARTMENT_ID <= dept_no;
  CURSOR c3(dept_no NUMBER DEFAULT 10) IS
    SELECT * FROM DEPARTMENTS
    WHERE DEPARTMENTS.DEPARTMENT_ID <=dept_no;
BEGIN
  OPEN c1;
  LOOP
    FETCH c1 INTO dept_name, dept_loc;
    EXIT WHEN c1%NOTFOUND;
        DBMS_OUTPUT.PUT_LINE(dept_name||'---'||dept_loc);
    END LOOP;
    CLOSE c1;

    OPEN c2;
    LOOP
        FETCH c2 INTO dept_name, dept_loc;
        EXIT WHEN c2%NOTFOUND;
        DBMS_OUTPUT.PUT_LINE(dept_name||'---'||dept_loc);
    END LOOP;
    CLOSE c2;

    OPEN c3(dept_no =>20);
    LOOP
        FETCH c3 INTO deptrec;
        EXIT WHEN c3%NOTFOUND;
        DBMS_OUTPUT.PUT_LINE(deptrec.DEPARTMENT_ID||'---'||deptrec.DEPARTMENT_NAME||'---'||deptrec.LOCATION_ID);
    END LOOP;
    CLOSE c3;
END;

2.游標(biāo)屬性

Cursor_name%FOUND 布爾型屬性，當(dāng)最近一次提取游標(biāo)操作FETCH成功則為 TRUE,否則為FALSE；

Cursor_name%NOTFOUND 布爾型屬性，與%FOUND相反；

Cursor_name%ISOPEN 布爾型屬性，當(dāng)游標(biāo)已打開時(shí)返回 TRUE；

Cursor_name%ROWCOUNT 數(shù)字型屬性，返回已從游標(biāo)中讀取的記錄數(shù)。

例3：給工資低于1200 的員工增加工資50。

DECLARE
   v_empno  EMPLOYEES.EMPLOYEE_ID%TYPE;
   v_sal      EMPLOYEES.Salary%TYPE;
   CURSOR c_cursor IS SELECT EMPLOYEE_ID, Salary FROM EMPLOYEES;
BEGIN
   OPEN c_cursor;
   LOOP
      FETCH c_cursor INTO v_empno, v_sal;
      EXIT WHEN c_cursor%NOTFOUND;
      IF v_sal<=1200 THEN
            UPDATE EMPLOYEES SET Salary=Salary+50 WHERE EMPLOYEE_ID=v_empno;
            DBMS_OUTPUT.PUT_LINE('編碼為'||v_empno||'工資已更新!');
      END IF;
   DBMS_OUTPUT.PUT_LINE('記錄數(shù):'|| c_cursor %ROWCOUNT);
   END LOOP;
   CLOSE c_cursor;
END;

例4：沒有參數(shù)且沒有返回值的游標(biāo)。

DECLARE
   v_f_name employees.first_name%TYPE;
   v_j_id   employees.job_id%TYPE;
   CURSOR c1       --聲明游標(biāo),沒有參數(shù)沒有返回值
   IS
      SELECT first_name, job_id FROM employees
      WHERE department_id = 20;
BEGIN
   OPEN c1;        --打開游標(biāo)
   LOOP
      FETCH c1 INTO v_f_name, v_j_id;    --提取游標(biāo)
      IF c1%FOUND THEN
         DBMS_OUTPUT.PUT_LINE(v_f_name||'的崗位是'||v_j_id);
      ELSE
         DBMS_OUTPUT.PUT_LINE('已經(jīng)處理完結(jié)果集了');
         EXIT;
      END IF;
   END LOOP;
   CLOSE c1;   --關(guān)閉游標(biāo)
END;

例5：有參數(shù)且沒有返回值的游標(biāo)。

DECLARE
   v_f_name employees.first_name%TYPE;
   v_h_date employees.hire_date%TYPE;
   CURSOR c2(dept_id NUMBER, j_id VARCHAR2) --聲明游標(biāo),有參數(shù)沒有返回值
   IS
      SELECT first_name, hire_date FROM employees
      WHERE department_id = dept_id AND job_id = j_id;
BEGIN
   OPEN c2(90, 'AD_VP');  --打開游標(biāo),傳遞參數(shù)值
   LOOP
      FETCH c2 INTO v_f_name, v_h_date;    --提取游標(biāo)
      IF c2%FOUND THEN
         DBMS_OUTPUT.PUT_LINE(v_f_name||'的雇傭日期是'||v_h_date);
      ELSE
         DBMS_OUTPUT.PUT_LINE('已經(jīng)處理完結(jié)果集了');
         EXIT;
      END IF;
   END LOOP;
   CLOSE c2;   --關(guān)閉游標(biāo)
END;

例6：有參數(shù)且有返回值的游標(biāo)。

DECLARE
   TYPE emp_record_type IS RECORD(
        f_name   employees.first_name%TYPE,
        h_date   employees.hire_date%TYPE);
   v_emp_record EMP_RECORD_TYPE;

   CURSOR c3(dept_id NUMBER, j_id VARCHAR2) --聲明游標(biāo),有參數(shù)有返回值
          RETURN EMP_RECORD_TYPE
   IS
      SELECT first_name, hire_date FROM employees
      WHERE department_id = dept_id AND job_id = j_id;
BEGIN
   OPEN c3(j_id => 'AD_VP', dept_id => 90);  --打開游標(biāo),傳遞參數(shù)值
   LOOP
      FETCH c3 INTO v_emp_record;    --提取游標(biāo)
      IF c3%FOUND THEN
         DBMS_OUTPUT.PUT_LINE(v_emp_record.f_name||'的雇傭日期是'
                            ||v_emp_record.h_date);
      ELSE
         DBMS_OUTPUT.PUT_LINE('已經(jīng)處理完結(jié)果集了');
         EXIT;
      END IF;
   END LOOP;
   CLOSE c3;   --關(guān)閉游標(biāo)
END;

例7：基于游標(biāo)定義記錄變量。

DECLARE
   CURSOR c4(dept_id NUMBER, j_id VARCHAR2) --聲明游標(biāo),有參數(shù)沒有返回值
   IS
      SELECT first_name f_name, hire_date FROM employees
      WHERE department_id = dept_id AND job_id = j_id;
    --基于游標(biāo)定義記錄變量，比聲明記錄類型變量要方便，不容易出錯(cuò)
    v_emp_record c4%ROWTYPE;
BEGIN
   OPEN c4(90, 'AD_VP');  --打開游標(biāo),傳遞參數(shù)值
   LOOP
      FETCH c4 INTO v_emp_record;    --提取游標(biāo)
      IF c4%FOUND THEN
         DBMS_OUTPUT.PUT_LINE(v_emp_record.f_name||'的雇傭日期是'
                            ||v_emp_record.hire_date);
      ELSE
         DBMS_OUTPUT.PUT_LINE('已經(jīng)處理完結(jié)果集了');
         EXIT;
      END IF;
   END LOOP;
   CLOSE c4;   --關(guān)閉游標(biāo)
END;

3. 游標(biāo)的FOR循環(huán)

PL/SQL語言提供了游標(biāo)FOR循環(huán)語句，自動(dòng)執(zhí)行游標(biāo)的OPEN、FETCH、CLOSE語句和循環(huán)語句的功能；當(dāng)進(jìn)入循環(huán)時(shí)，游標(biāo)FOR循環(huán)語句自動(dòng)打開游標(biāo)，并提取第一行游標(biāo)數(shù)據(jù)，當(dāng)程序處理完當(dāng)前所提取的數(shù)據(jù)而進(jìn)入下一次循環(huán)時(shí)，游標(biāo)FOR循環(huán)語句自動(dòng)提取下一行數(shù)據(jù)供程序處理，當(dāng)提取完結(jié)果集合中的所有數(shù)據(jù)行后結(jié)束循環(huán)，并自動(dòng)關(guān)閉游標(biāo)。

格式：

  FOR index_variable IN cursor_name[(value[, value]…)] LOOP
    -- 游標(biāo)數(shù)據(jù)處理代碼
  END LOOP;

其中：

index_variable為游標(biāo)FOR 循環(huán)語句隱含聲明的索引變量，該變量為記錄變量，其結(jié)構(gòu)與游標(biāo)查詢語句返回的結(jié)構(gòu)集合的結(jié)構(gòu)相同。在程序中可以通過引用該索引記錄變量元素來讀取所提取的游標(biāo)數(shù)據(jù)，index_variable中各元素的名稱與游標(biāo)查詢語句選擇列表中所制定的列名相同。如果在游標(biāo)查詢語句的選擇列表中存在計(jì)算列，則必須為這些計(jì)算列指定別名后才能通過游標(biāo)FOR 循環(huán)語句中的索引變量來訪問這些列數(shù)據(jù)。

注：不要在程序中對游標(biāo)進(jìn)行人工操作；不要在程序中定義用于控制FOR循環(huán)的記錄。

例8：

DECLARE
   CURSOR c_sal IS SELECT employee_id, first_name || last_name ename, salary
   FROM employees ;
BEGIN
   --隱含打開游標(biāo)
   FOR v_sal IN c_sal LOOP
   --隱含執(zhí)行一個(gè)FETCH語句
      DBMS_OUTPUT.PUT_LINE(to_char(v_sal.employee_id)||'---'|| v_sal.ename||'---'||to_char(v_sal.salary)) ;
   --隱含監(jiān)測c_sal%NOTFOUND
   END LOOP;
--隱含關(guān)閉游標(biāo)
END;

例9：當(dāng)所聲明的游標(biāo)帶有參數(shù)時(shí)，通過游標(biāo)FOR 循環(huán)語句為游標(biāo)傳遞參數(shù)。

DECLARE
  CURSOR c_cursor(dept_no NUMBER DEFAULT 10)
  IS
    SELECT department_name, location_id FROM departments WHERE department_id <= dept_no;
BEGIN
    DBMS_OUTPUT.PUT_LINE('當(dāng)dept_no參數(shù)值為30：');
    FOR c1_rec IN c_cursor(30) LOOP        DBMS_OUTPUT.PUT_LINE(c1_rec.department_name||'---'||c1_rec.location_id);
    END LOOP;
    DBMS_OUTPUT.PUT_LINE(CHR(10)||'使用默認(rèn)的dept_no參數(shù)值10：');
    FOR c1_rec IN c_cursor LOOP        DBMS_OUTPUT.PUT_LINE(c1_rec.department_name||'---'||c1_rec.location_id);
    END LOOP;
END;

例10：PL/SQL還允許在游標(biāo)FOR循環(huán)語句中使用子查詢來實(shí)現(xiàn)游標(biāo)的功能。

BEGIN
FOR c1_rec IN(SELECT department_name, location_id FROM departments) LOOP DBMS_OUTPUT.PUT_LINE(c1_rec.department_name||'---'||c1_rec.location_id);
END LOOP;
END;

4.1.2 處理隱式游標(biāo)

顯式游標(biāo)主要是用于對查詢語句的處理，尤其是在查詢結(jié)果為多條記錄的情況下；而對于非查詢語句，如修改、刪除操作，則由ORACLE 系統(tǒng)自動(dòng)地為這些操作設(shè)置游標(biāo)并創(chuàng)建其工作區(qū)，這些由系統(tǒng)隱含創(chuàng)建的游標(biāo)稱為隱式游標(biāo)，隱式游標(biāo)的名字為SQL，這是由ORACLE 系統(tǒng)定義的。對于隱式游標(biāo)的操作，如定義、打開、取值及關(guān)閉操作，都由ORACLE 系統(tǒng)自動(dòng)地完成，無需用戶進(jìn)行處理。用戶只能通過隱式游標(biāo)的相關(guān)屬性，來完成相應(yīng)的操作。在隱式游標(biāo)的工作區(qū)中，所存放的數(shù)據(jù)是與用戶自定義的顯示游標(biāo)無關(guān)的、最新處理的一條SQL 語句所包含的數(shù)據(jù)。

格式調(diào)用為： SQL%

注：INSERT, UPDATE, DELETE, SELECT 語句中不必明確定義游標(biāo)。

隱式游標(biāo)屬性

屬性	值	SELECT	INSERT	UPDATE	DELETE
SQL%ISOPEN		FALSE	FALSE	FALSE	FALSE
SQL%FOUND	TRUE	有結(jié)果		成功	成功
SQL%FOUND	FALSE	沒結(jié)果		失敗	失敗
SQL%NOTFUOND	TRUE	沒結(jié)果		失敗	失敗
SQL%NOTFOUND	FALSE	有結(jié)果		成功	失敗
SQL%ROWCOUNT		返回行數(shù)，只為1	插入的行數(shù)	修改的行數(shù)	刪除的行數(shù)

例11: 刪除EMPLOYEES表中某部門的所有員工，如果該部門中已沒有員工，則在DEPARTMENT表中刪除該部門。

DECLARE
    V_deptno department_id%TYPE :=&p_deptno;
BEGIN
    DELETE FROM employees WHERE department_id=v_deptno;
    IF SQL%NOTFOUND THEN
        DELETE FROM departments WHERE department_id=v_deptno;
    END IF;
END;

例12: 通過隱式游標(biāo)SQL的%ROWCOUNT屬性來了解修改了多少行。

DECLARE
   v_rows NUMBER;
BEGIN
--更新數(shù)據(jù)
   UPDATE employees SET salary = 30000
   WHERE department_id = 90 AND job_id = 'AD_VP';
--獲取默認(rèn)游標(biāo)的屬性值
   v_rows := SQL%ROWCOUNT;
   DBMS_OUTPUT.PUT_LINE('更新了'||v_rows||'個(gè)雇員的工資');
--回退更新，以便使數(shù)據(jù)庫的數(shù)據(jù)保持原樣
   ROLLBACK;
END;

4.1.3 關(guān)于 NO_DATA_FOUND 和 %NOTFOUND的區(qū)別

SELECT … INTO 語句觸發(fā) NO_DATA_FOUND；

當(dāng)一個(gè)顯式游標(biāo)的WHERE子句未找到時(shí)觸發(fā)%NOTFOUND；

當(dāng)UPDATE或DELETE 語句的WHERE 子句未找到時(shí)觸發(fā) SQL%NOTFOUND；在提取循環(huán)中要用 %NOTFOUND 或%FOUND 來確定循環(huán)的退出條件，不要用 NO_DATA_FOUND.4.1.4 使用游標(biāo)更新和刪除數(shù)據(jù)

游標(biāo)修改和刪除操作是指在游標(biāo)定位下，修改或刪除表中指定的數(shù)據(jù)行。這時(shí)，要求游標(biāo)查詢語句中必須使用FOR UPDATE選項(xiàng)，以便在打開游標(biāo)時(shí)鎖定游標(biāo)結(jié)果集合在表中對應(yīng)數(shù)據(jù)行的所有列和部分列。

為了對正在處理(查詢)的行不被另外的用戶改動(dòng)，ORACLE 提供一個(gè) FOR UPDATE 子句來對所選擇的行進(jìn)行鎖住。該需求迫使ORACLE鎖定游標(biāo)結(jié)果集合的行，可以防止其他事務(wù)處理更新或刪除相同的行，直到您的事務(wù)處理提交或回退為止。

語法：

SELECT column_list FROM table_list FOR UPDATE [OF column[, column]…] [NOWAIT]

如果另一個(gè)會(huì)話已對活動(dòng)集中的行加了鎖，那么SELECT FOR UPDATE操作一直等待到其它的會(huì)話釋放這些鎖后才繼續(xù)自己的操作，對于這種情況，當(dāng)加上NOWAIT子句時(shí)，如果這些行真的被另一個(gè)會(huì)話鎖定，則OPEN立即返回并給出：

ORA-0054 ：resource busy and acquire with nowait specified.

如果使用 FOR UPDATE 聲明游標(biāo)，則可在DELETE和UPDATE 語句中使用

WHERE CURRENT OF cursor_name子句，修改或刪除游標(biāo)結(jié)果集合當(dāng)前行對應(yīng)的數(shù)據(jù)庫表中的數(shù)據(jù)行。

例13：從EMPLOYEES表中查詢某部門的員工情況，將其工資最低定為 1500；

DECLARE
    V_deptno employees.department_id%TYPE :=&p_deptno;
    CURSOR emp_cursor
  IS
  SELECT employees.employee_id, employees.salary
    FROM employees WHERE employees.department_id=v_deptno
  FOR UPDATE NOWAIT;
BEGIN
    FOR emp_record IN emp_cursor LOOP
    IF emp_record.salary < 1500 THEN
        UPDATE employees SET salary=1500
    WHERE CURRENT OF emp_cursor;
    END IF;
    END LOOP;
--    COMMIT;
END;

例14：將EMPLOYEES表中部門編碼為90、崗位為AD_VP的雇員的工資都更新為2000元；

DECLARE
   v_emp_record employees%ROWTYPE;
   CURSOR c1
   IS
      SELECT * FROM employees FOR UPDATE;
BEGIN
   OPEN c1;
   LOOP
      FETCH c1 INTO v_emp_record;
      EXIT WHEN c1%NOTFOUND;
      IF v_emp_record.department_id = 90 AND
         v_emp_record.job_id = 'AD_VP'
      THEN
         UPDATE employees SET salary = 20000
         WHERE CURRENT OF c1;  --更新當(dāng)前游標(biāo)行對應(yīng)的數(shù)據(jù)行
      END IF;
   END LOOP;
   COMMIT;   --提交已經(jīng)修改的數(shù)據(jù)
   CLOSE c1;
END;

4.2 游標(biāo)變量

與游標(biāo)一樣，游標(biāo)變量也是一個(gè)指向多行查詢結(jié)果集合中當(dāng)前數(shù)據(jù)行的指針。但與游標(biāo)不同的是，游標(biāo)變量是動(dòng)態(tài)的，而游標(biāo)是靜態(tài)的。游標(biāo)只能與指定的查詢相連，即固定指向一個(gè)查詢的內(nèi)存處理區(qū)域，而游標(biāo)變量則可與不同的查詢語句相連，它可以指向不同查詢語句的內(nèi)存處理區(qū)域（但不能同時(shí)指向多個(gè)內(nèi)存處理區(qū)域，在某一時(shí)刻只能與一個(gè)查詢語句相連），只要這些查詢語句的返回類型兼容即可。

4.2.1 聲明游標(biāo)變量

游標(biāo)變量為一個(gè)指針，它屬于參照類型，所以在聲明游標(biāo)變量類型之前必須先定義游標(biāo)變量類型。在PL/SQL中，可以在塊、子程序和包的聲明區(qū)域內(nèi)定義游標(biāo)變量類型。

語法格式為：

TYPE ref_type_name IS REF CURSOR
[ RETURN return_type];

其中：ref_type_name為新定義的游標(biāo)變量類型名稱；

return_type 為游標(biāo)變量的返回值類型，它必須為記錄變量。

在定義游標(biāo)變量類型時(shí)，可以采用強(qiáng)類型定義和弱類型定義兩種。強(qiáng)類型定義必須指定游標(biāo)變量的返回值類型，而弱類型定義則不說明返回值類型。

聲明一個(gè)游標(biāo)變量的兩個(gè)步驟：

步驟一：定義一個(gè)REF CURSOU數(shù)據(jù)類型，如：

TYPE ref_cursor_type IS REF CURSOR;

步驟二：聲明一個(gè)該數(shù)據(jù)類型的游標(biāo)變量，如：

cv_ref REF_CURSOR_TYPE;

例：創(chuàng)建兩個(gè)強(qiáng)類型定義游標(biāo)變量和一個(gè)弱類型游標(biāo)變量：

DECLARE
    TYPE deptrecord IS RECORD(
        Deptno departments.department_id%TYPE,
        Dname departments.department_name%TYPE,
        Loc departments.location_id%TYPE
    );
    TYPE deptcurtype IS REF CURSOR RETURN departments%ROWTYPE;
    TYPE deptcurtyp1 IS REF CURSOR RETURN deptrecord;
    TYPE curtype IS REF CURSOR;
    Dept_c1 deptcurtype;
    Dept_c2 deptcurtyp1;
    Cv curtype;

4.2.2 游標(biāo)變量操作

與游標(biāo)一樣，游標(biāo)變量操作也包括打開、提取和關(guān)閉三個(gè)步驟。

1．打開游標(biāo)變量

打開游標(biāo)變量時(shí)使用的是OPEN…FOR 語句。格式為：

OPEN {cursor_variable_name | :host_cursor_variable_name}
FOR select_statement;

其中：cursor_variable_name為游標(biāo)變量，host_cursor_variable_name為PL/SQL主機(jī)環(huán)境（如OCI: ORACLE Call Interface，Pro*c 程序等）中聲明的游標(biāo)變量。

OPEN…FOR 語句可以在關(guān)閉當(dāng)前的游標(biāo)變量之前重新打開游標(biāo)變量，而不會(huì)導(dǎo)致CURSOR_ALREAD_OPEN異常錯(cuò)誤。新打開游標(biāo)變量時(shí)，前一個(gè)查詢的內(nèi)存處理區(qū)將被釋放。

2．提取游標(biāo)變量數(shù)據(jù)

使用FETCH語句提取游標(biāo)變量結(jié)果集合中的數(shù)據(jù)。格式為：

FETCH {cursor_variable_name | :host_cursor_variable_name}
INTO {variable [, variable]…| record_variable};

其中：cursor_variable_name和host_cursor_variable_name分別為游標(biāo)變量和宿主游標(biāo)變量名稱；variable和record_variable分別為普通變量和記錄變量名稱。

3．關(guān)閉游標(biāo)變量

CLOSE語句關(guān)閉游標(biāo)變量，格式為：

CLOSE {cursor_variable_name | :host_cursor_variable_name}

其中：cursor_variable_name和host_cursor_variable_name分別為游標(biāo)變量和宿主游標(biāo)變量名稱，如果應(yīng)用程序試圖關(guān)閉一個(gè)未打開的游標(biāo)變量，則將導(dǎo)致INVALID_CURSOR異常錯(cuò)誤。

例15：強(qiáng)類型參照游標(biāo)變量類型

DECLARE
    TYPE emp_job_rec IS RECORD(
        Employee_id employees.employee_id%TYPE,
        Employee_name employees.first_name%TYPE,
        Job_title employees.job_id%TYPE
    );
    TYPE emp_job_refcur_type IS REF CURSOR RETURN emp_job_rec;
    Emp_refcur emp_job_refcur_type ;
    Emp_job emp_job_rec;
BEGIN
    OPEN emp_refcur FOR
    SELECT employees.employee_id, employees.first_name||employees.last_name, employees.job_id
  FROM employees
  ORDER BY employees.department_id;

    FETCH emp_refcur INTO emp_job;
    WHILE emp_refcur%FOUND LOOP
       DBMS_OUTPUT.PUT_LINE(emp_job.employee_id||': '||emp_job.employee_name||' is a '||emp_job.job_title);
    FETCH emp_refcur INTO emp_job;
    END LOOP;
END;

例16：弱類型參照游標(biāo)變量類型

PROMPT
PROMPT 'What table would you like to see?'
ACCEPT tab PROMPT '(D)epartment, or (E)mployees:'

DECLARE
    Type refcur_t IS REF CURSOR;
    Refcur refcur_t;
    TYPE sample_rec_type IS RECORD (
        Id number,
        Description VARCHAR2 (30)
    );
    sample sample_rec_type;
    selection varchar2(1) := UPPER (SUBSTR ('&tab', 1, 1));
BEGIN
    IF selection='D' THEN
        OPEN refcur FOR
    SELECT departments.department_id, departments.department_name FROM departments;
        DBMS_OUTPUT.PUT_LINE('Department data');
    ELSIF selection='E' THEN
        OPEN refcur FOR
    SELECT employees.employee_id, employees.first_name||' is a '||employees.job_id FROM employees;
        DBMS_OUTPUT.PUT_LINE('Employee data');
    ELSE
        DBMS_OUTPUT.PUT_LINE('Please enter ''D'' or ''E''');
        RETURN;
    END IF;
    DBMS_OUTPUT.PUT_LINE('----------------------');
    FETCH refcur INTO sample;
    WHILE refcur%FOUND LOOP
        DBMS_OUTPUT.PUT_LINE(sample.id||': '||sample.description);
        FETCH refcur INTO sample;
    END LOOP;
    CLOSE refcur;
END;

例17：使用游標(biāo)變量（沒有RETURN子句）

DECLARE
--定義一個(gè)游標(biāo)數(shù)據(jù)類型
   TYPE emp_cursor_type IS REF CURSOR;
--聲明一個(gè)游標(biāo)變量
   c1 EMP_CURSOR_TYPE;
--聲明兩個(gè)記錄變量
   v_emp_record employees%ROWTYPE;
   v_reg_record regions%ROWTYPE;

BEGIN
   OPEN c1 FOR SELECT * FROM employees WHERE department_id = 20;
   LOOP
      FETCH c1 INTO v_emp_record;
      EXIT WHEN c1%NOTFOUND;
      DBMS_OUTPUT.PUT_LINE(v_emp_record.first_name||'的雇傭日期是'
                            ||v_emp_record.hire_date);
   END LOOP;
--將同一個(gè)游標(biāo)變量對應(yīng)到另一個(gè)SELECT語句
   OPEN c1 FOR SELECT * FROM regions WHERE region_id IN（1，2）;
   LOOP
      FETCH c1 INTO v_reg_record;
      EXIT WHEN c1%NOTFOUND;
      DBMS_OUTPUT.PUT_LINE(v_reg_record.region_id||'表示'
                            ||v_reg_record.region_name);
   END LOOP;
   CLOSE c1;
END;

例18：使用游標(biāo)變量（有RETURN子句）

DECLARE
--定義一個(gè)與employees表中的這幾個(gè)列相同的記錄數(shù)據(jù)類型
   TYPE emp_record_type IS RECORD(
        f_name   employees.first_name%TYPE,
        h_date   employees.hire_date%TYPE,
        j_id     employees.job_id%TYPE);
--聲明一個(gè)該記錄數(shù)據(jù)類型的記錄變量
   v_emp_record EMP_RECORD_TYPE;
--定義一個(gè)游標(biāo)數(shù)據(jù)類型
   TYPE emp_cursor_type IS REF CURSOR
        RETURN EMP_RECORD_TYPE;
--聲明一個(gè)游標(biāo)變量
   c1 EMP_CURSOR_TYPE;
BEGIN
   OPEN c1 FOR SELECT first_name, hire_date, job_id
               FROM employees WHERE department_id = 20;
   LOOP
      FETCH c1 INTO v_emp_record;
      EXIT WHEN c1%NOTFOUND;
      DBMS_OUTPUT.PUT_LINE('雇員名稱：'||v_emp_record.f_name
                ||'  雇傭日期：'||v_emp_record.h_date
                ||'  崗位：'||v_emp_record.j_id);
   END LOOP;
   CLOSE c1;
END;

posted on 2012-09-12 17:31 kxbin 閱讀(284) 評論(0) 編輯收藏所屬分類: ORACLE 、轉(zhuǎn)發(fā)

4.1 游標(biāo)概念

4.1.1 處理顯式游標(biāo)

4.1.3 關(guān)于 NO_DATA_FOUND 和 %NOTFOUND的區(qū)別

4.2 游標(biāo)變量

4.2.1 聲明游標(biāo)變量

常用鏈接

留言簿(5)

隨筆檔案

文章分類

文章檔案

相冊

收藏夾

J2EE

java技術(shù)網(wǎng)站

Linux

平時(shí)常去的網(wǎng)站

數(shù)據(jù)庫

電影網(wǎng)站

網(wǎng)站設(shè)計(jì)

搜索

最新評論

閱讀排行榜

評論排行榜


只有注冊用戶登錄后才能發(fā)表評論。




網(wǎng)站導(dǎo)航: 博客園 IT新聞 Chat2DB C++博客博問管理
相關(guān)文章: win7 64位系統(tǒng) pl sql 無法解析指定的連接標(biāo)識(shí)符解決辦法 oracle SQL語句執(zhí)行步驟 linux oracle10g安裝 ORACLE鎖機(jī)制 Oracle 數(shù)據(jù)庫實(shí)例啟動(dòng)關(guān)閉過程 oracle for update和for update nowait的區(qū)別（二） oracle for update和for update nowait的區(qū)別（一） Oracle10g安裝了11g的ODAC后，PL/SQL連接提示TNS：無法解析指定的連接標(biāo)識(shí)符 ORACLE常用命令 Oracle同義詞創(chuàng)建及其作用