Winsock控件建立在TCP、UDP協議的基礎上，完成與遠程計算機的通信。即使對TCP/IP不太熟悉的用戶，使用該控件也可以在十幾分鐘內創建一 個簡單的客戶機/服務器程序。下面我們對Winsock控件的事件、方法、屬性按其在程序中出現的順序分別作詳細的介紹，以便更好地理解程序源代碼。
下面是Winsock控件的相關屬性，方法和事件。(略去一些暫用不到的)
*屬性
-------------------------------------------------------------------------
LocalHostName | 本地機器名
LocalIP | 本地機器IP地址
LocalPort | 本地機器通信程序的端口(0 <端口 <65536)
RemoteHost | 遠程機器名
RemotePort | 遠程機器的通信程序端口
state | 連接的當前狀態(文后有詳細說明)
Protocal | 使用TCP或UDP協議(這里我們選‘0-sckTCPProtocal’)
--------------------------------------------------------------------------
*方法
--------------------------------------------------------------------------
Listen
Listen方法用于服務器程序，等待客戶訪問。
格式：Winsock對象.listen
Connect
Connect方法用于向遠程主機發出連接請求
格式：Winsock對象.connect [遠程主機IP,遠程端口]
Accept
Accept方法用于接受一個連接請求
格式：Winsock對象.accept Request ID
Senddata
此方法用于發送數據
格式：Winsock對象.senddata 數據
Getdata
用來取得接收到的數據
格式：Winsock對象.getdata 變量 [,數據類型 [,最大長度]]
Close
關閉當前連接
格式：Winsock對象.close
*事件
----------------------------------------------------------------------------
Close | 遠程機器關閉連接時觸發
Connect | 連接建立好，可以進行通信時觸發(客戶端)
ConnectRequest | 有請求連接到達時產生(服務器端)
DataArrival | 有數據到達時觸發
Error | 發生錯誤時發生
SendProgress | 數據傳送進度
-----------------------------------------------------------------------------

服務器程序的實現過程是：
（1）服務器程序必須設置好LocalPort屬性，作為偵聽端口，該值為一個整數（只要是一個其它TCP/IP應用程序沒有使用過的值即可）。
（2）使用Listen方法進入偵聽狀態，等待客戶機程序的連接請求。
（3）客戶機程序發出連接請求，使服務器程序產生ConnectionRequest事件，該事件得到一個參數requestID。
（4）服務器程序用Accept方法接受客戶機程序的requestID請求。這樣，服務器程序就可以用SendData方法發送數據了。Accept方法必須用上一步得到的requestID作為其參數。
（5）當服務器程序接收到數據時，產生DataArrival事件，參數BytesTotal包含接收到的數據字節數。在該事件中，可以用GetData方法接收數據。
（6）如果接受到Close事件，則用Close方法關閉TCP/IP連接。
客戶機程序的實現過程是：
（1） 客戶程序設置Remotehost屬性，以便指定運行服務器程序的主機 名，該字符串可在“控制面板|網絡|標識|計算機名”中查到。
（2） 設置RemotePort屬性,以便指定服務器程序的偵聽端口。
（3）使用Connect方法，向服務器提出連接請求。
（4）服務器接受客戶機程序的請求，客戶機程序產生Connect事件，就可以用SendData方法發送數據了。
（5）當客戶機程序接收到數據時，產生DataArrival事件，參數BytesTotal包含接收到的數據字節數。在該事件中，可以用GetData方法接收數據。
（6）如果接受到Close事件，則用Close方法關閉連接。
Winsock控件還有兩個重要的屬性，即Protocol和State。Protocol設定使用的協議是TCP還是UDP：取值 sckTCPProtocol表示TCP, 取值sckUDPProtocol則表示UDP。因為Winsock控件的缺省設置是sckTCPProtocol，所以程序中并沒有使用 Protocol屬性。State屬性反映的是當前TCP/IP的連接狀態，取值如表1所示。
表1 Winsock控件的State屬性及其描述
常數 值 描述
SckClosed 0 缺省值，關閉
SckOpen 1 打開
SckListening 2 偵聽
SckConnectionPending 3 連接掛起
SckResolvingHost 4 識別主機
SckHostResolved 5 已識別主機
SckConnecting 6 正在連接
SckConnected 7 已連接
SckClosing 8 同級人員正在關閉連接
SckError 9 錯誤
先在一臺計算機上運行服務器程序，此時窗口上只有一個“退出”按鈕。 再在另一臺計算機上運行客戶機程序，在“連接”按鈕右邊的文本框中輸入服務器的主機名后單擊“連接”按鈕。如果連接成功，則服務器和客戶機程序窗口都會出 現兩個文本框。這時，兩端都可以在上面的文本框中輸入文字，這些文字會立即在下面的文本框中出現。
服務器程序使用的控件如下：
（1）Command1：退出按鈕；
（2）textsend：發送數據文本框；
（3）Winsockserver： 服務器Winsock；
（4）textget ：接收數據文本框。
服務器程序的界面如圖所示。
服務器程序的源代碼如下：
Private Sub Command1_Click()
End
End Sub
Private Sub Form_Load()
textsend.Visible = False
textget.Visible = False
Winsockserver.LocalPort = 1001
Winsockserver.Listen
End Sub

Private Sub textsend_Change()
Winsockserver.SendData textsend.Text
End Sub
Private Sub Winsockserver_Close()
Winsockserver.Close
End
End Sub

Private Sub Winsockserver_ConnectionRequest(ByVal requestID As Long)
textsend.Visible = True
textget.Visible = True
If Winsockserver.State <> sckClosed Then Winsockserver.Close
Winsockserver.Accept requestID
End Sub

Private Sub Winsockserver_DataArrival(ByVal bytesTotal As Long)
Dim tmpstr As String

Winsockserver.GetData tmpstr
textget.Text = tmpstr
End Sub

客戶機程序使用的控件如下：
（1）Command1：退出按鈕；
（2）Command2：連接按鈕；
（3）Winsockclient：客戶Winsock；
（4）Text1：主機名文本框；
（5）Textsend：發送數據文本框；
（6）Textget：接收數據文本框； 　　
客戶機程序的源代碼如下：
Private Sub Command1_Click()
End
End Sub
Private Sub Command2_Click()
Winsockclient.Connect
End Sub
Private Sub Form_Load()
textsend.Visible = False
textget.Visible = False
Winsockclient.RemotePort = 1001
Winsockclient.RemoteHost = "sccdsz"
End Sub
Private Sub Text1_Change()
Winsockclient.RemoteHost = Text1.Text
End Sub
Private Sub textsend_Change()
Winsockclient.SendData textsend.Text
End Sub
Private Sub Winsockclient_Close()
Winsockclient.Close
End
End Sub
Private Sub winsockclient_Connect()
textsend.Visible = True
textget.Visible = True
Command2.Visible = False
End Sub
Private Sub winsockclient_DataArrival(ByVal bytesTotal As Long)
Dim tmpstr As String
Winsockclient.GetData tmpstr
textget.Text = tmpstr
End Sub

我試過了，可以用